Mi acer aspire one es con 1gb de ram y disco duro 160gb y el famoso procesador atom de intel de 1.6. con Windows XP Home

Deben abrir el block de notas (asegurarse que pueden salvar con cualquier extension eso de cuando hacemos Herramientas->Opciones de Carpeta->desmarcar Esconder extensiones para tipos de archivo conocido)

copian el siguiente codigo
''''inicio codigo ''''
' Visual Basic Script program to reset the DMA status of all ATA drives

' Copyright © 2006 Hans-Georg Michna

' Version 2007-04-04

' Works in Windows XP, probably also in Windows 2000 and NT.
' Does no harm if Windows version is incompatible.

If MsgBox("This program will now reset the DMA status of all ATA drives with Windows drivers." _
& vbNewline & "Windows will redetect the status after the next reboot, therefore this procedure" _
& vbNewline & "should be harmless.", _
vbOkCancel, "Program start message") _
= vbOk Then

RegPath = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Class\{4D36E96A-E325-11CE-BFC1-08002BE10318}\"
ValueName1Master = "MasterIdDataChecksum"
ValueName1Slave = "SlaveIdDataChecksum"
ValueName2Master = "UserMasterDeviceTimingModeAllowed"
ValueName2Slave = "UserSlaveDeviceTimingModeAllowed"
ValueName3 = "ResetErrorCountersOnSuccess"
MessageText = "The following ATA channels have been reset:"
MessageTextLen0 = Len(MessageText)
ConsecutiveMisses = 0
Set WshShell = WScript.CreateObject("WScript.Shell")

For i = 0 to 999
RegSubPath = Right("000" & i, 4) & "\"

' Master

Err.Clear
On Error Resume Next
WshShell.RegRead RegPath & RegSubPath & ValueName1Master
errMaster = Err.Number
On Error Goto 0
If errMaster = 0 Then
On Error Resume Next
WshShell.RegDelete RegPath & RegSubPath & ValueName1Master
WshShell.RegDelete RegPath & RegSubPath & ValueName2Master
On Error Goto 0
MessageText = MessageText & vbNewLine & "Master"
End If

' Slave

Err.Clear
On Error Resume Next
WshShell.RegRead RegPath & RegSubPath & ValueName1Slave
errSlave = Err.Number
On Error Goto 0
If errSlave = 0 Then
On Error Resume Next
WshShell.RegDelete RegPath & RegSubPath & ValueName1Slave
WshShell.RegDelete RegPath & RegSubPath & ValueName2Slave
On Error Goto 0
If errMaster = 0 Then
MessageText = MessageText & " and "
Else
MessageText = MessageText & vbNewLine
End If
MessageText = MessageText & "Slave"
End If

If errMaster = 0 Or errSlave = 0 Then
On Error Resume Next
WshShell.RegWrite RegPath & RegSubPath & ValueName3, 1, "REG_DWORD"
On Error Goto 0
ChannelName = "unnamed channel " & Left(RegSubPath, 4)
On Error Resume Next
ChannelName = WshShell.RegRead(RegPath & RegSubPath & "DriverDesc")
On Error Goto 0
MessageText = MessageText & " of " & ChannelName & ";"
ConsecutiveMisses = 0
Else
ConsecutiveMisses = ConsecutiveMisses + 1
If ConsecutiveMisses >= 32 Then Exit For ' Don't search unnecessarily long.
End If
Next ' i

If Len(MessageText) <= MessageTextLen0 Then
MessageText = "No resettable ATA channels with Windows drivers found. Nothing changed."
Else
MessageText = MessageText & vbNewline _
& "Please reboot now to reset and redetect the DMA status."
End If

MsgBox MessageText, vbOkOnly, "Program finished normally"

End If ' MsgBox(...) = vbOk

' End of Visual Basic Script program

'' Fin codigo

Guardan en el bloc de notas con el nombre 'RESETDMA.VBS' sin las comillas
Luego para ejecutarlo nada mas darle clic al archivo y se ejecuta el script y bueno a mi me funciono
Suerte

GRACIAS A JAILHIRI QUE NOS PROPORRCIONO ESTA AYUDA A ESTE PROBLEMA QUE EN MI CASO YA ME TENIA MUY DESESPERADO, ME LLEVE TODO EL DIA BUSCANDO LA SOLUCION ALGO QUE HICE TAMBIEN FUE INSTALARLE EL XP PERO NO EL RECOVERY. CON UNA UNIDAD EXTERNA Y PARTICIONE MI DISCO

ACTUALIZE EL BIOS, NO SOLO MEJORO EL AUDIO SINO EL RENDIMIENTO EN GENERAL DE LA ACER ONE. MUY RECOMENDABLE

SALUDOS Y MUCHA SUERTE

Actualizastes el BIOS
pero...
a que version lo has hecho ??

Oh, sí. Ese código lo encontré en otro tema hace tiempo y también solucionó todos mis problemas con el audio. Además mejoró mi tiempo de arranque de 5 min aprox. a 1 min y medio. (WTF??!!!, pues sí, así es). Además, el Firefox, que tardaba como minuto y medio en abrirse, bajó a sólo 20 segs. Toda una maravilla!!! Ya después le hice muchas burradas al registro y la tuve que formatear con el Recovery u.u. Después del formateo y usar el código de nuevo ya sólo tardaba 55 segs en arrancar, ya con antivirus y todo. La BIOS no la he actualizado, he leído que no es muy recomendable, mejor así!

Wenas,
no me ha quedado muy claro, ese archivo que creas lo tienes que ejecutar siempre que inicias o con una vez ya te arregla el problema??
A mi el audio me va de lujo, pero si acelera el arranque como decis es para pensárselo.